手搓月饼

最近中秋节，看到群里面有 月饼加工图，于是也来整个烂活 打印月饼 试试。

建模的话 emmm 就懒得开 Fusion 360 了，还是使用 OpenSCAD 来进行吧。

分析

• 月饼主体： cylinder
• 周围是一圈小的 cylinder
• 文字使用 text 生成后用 linear_extrude 挤出
• 中间的圈用 difference() 两个 cylinder 来制作
• 花纹用 difference() 制作
• 月饼周围的斜面用月饼主体和一个很大的 sphere 进行 intersection() 来制作

建模

根据以上分析搓代码进行建模。

parametric_mooncake.scad

pi = 3.1415926;
segments = 24;
diameter = 50;
height = 17;
outer_displace = -2;
outer_d = diameter * pi / segments + 1;

decoration_type = 1;
text_frame = false;

intersection()
{
    union()
    {
        for(i=[0:1:segments])
        {
            x=cos(i*360/segments)*(diameter/2+outer_displace);
            y=sin(i*360/segments)*(diameter/2+outer_displace);
            
            translate([x,y,0])
                cylinder(d=outer_d,h=height, $fn=48);
        }
        
        if(decoration_type==1)
        {
            difference()
            {
                cylinder(d=diameter,h=height+.5,$fn=96);
                
                translate([0,0,height])
                union()
                {
                    rotate([0,0,10])
                    for(cx=[-7:1:7])
                    for(cy=[-5:1:5])
                    {
                        dx=cx%2;
                        translate([cx*5*sin(60),cy*5+dx*5/2,0])
                            cylinder(h=2,r=2.5,$fn=6);
                    }
            }}
        }
        else if(decoration_type==2)
        {
            cylinder(d=diameter,h=height,$fn=96);
            
            translate([0,0,height])
            for(i=[0:1:30])
            {
                x=cos(i*360/30)*(diameter/2-5);
                y=sin(i*360/30)*(diameter/2-5);
                
                translate([x,y,0])
                difference()
                {
                    cylinder(d=10,h=.5, $fn=48);
                    cylinder(d=8.5,h=2, $fn=48);
                }
            }
        }
        else if(decoration_type==3)
        {
            cylinder(d=diameter,h=height,$fn=96);
            
            translate([0,0,height])
            {
                lines=6;
                difference()
                {
                    cylinder(d=diameter,h=.5, $fn=lines);
                    cylinder(d=diameter-2,h=.5, $fn=lines);
                }
                rotate([0,0,360/16])
                difference()
                {
                    cylinder(d=diameter,h=.5, $fn=lines);
                    cylinder(d=diameter-2,h=.5, $fn=lines);
                }
            }
        }
        else if(decoration_type==4)
        {
            cylinder(d=diameter,h=height,$fn=96);
            for(cx=[-10:1:10])
                translate([cx*4,-35,height])
                    cube([.8,70,0.5]);    
            
            for(cy=[-10:1:10])
                translate([-35,cy*4,height])
                    cube([70,.8,0.5]);    
                
        }
        
    }
    
    translate([0,0,-42.3])
        sphere(d=130);

}    

translate([0,0,height])
{
    difference()
    {
        cylinder(d=diameter -9,h=.5+1,$fn=48);
        cylinder(d=diameter -11,h=2,$fn=48);
    }
    
    difference()
    {
        cylinder(d=diameter -14,h=.5+1,$fn=48);
        cylinder(d=diameter -15,h=2,$fn=48);
    }
    
    cylinder(d=diameter -10, h=.5,$fn=96);
}

if(text_frame)
{
    translate([0,0,height])
    {
        difference()
        {
            cube([17,28,1+1], center=true);
            cube([17-1.5,28-1.5,2+1], center=true);
        }
    }
}

translate([0,0,height])
linear_extrude(1.5)
{
    text("糊", size = 21, font = "楷体", halign = "center", valign = "center");
    
    /*text("莲", size = 10, font = "楷体", halign = "center", valign = "bottom");
    text("蓉", size = 10, font = "楷体", halign = "center", valign = "top");*/
}

生成 stl：

打印

导出 4 种花纹和文字的 stl，直接使用 bambu studio 切片后用竹子打印。

• material: PLA
• nozzle: 0.4mm
• layer: 0.2mm

出锅！

看起来很好吃（